1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
|
;;; piem-gnus.el --- Gnus integration for piem -*- lexical-binding: t; -*-
;; Copyright all piem contributors <piem@inbox.kyleam.com>
;; Author: Kyle Meyer <kyle@kyleam.com>
;; Keywords: vc, tools
;; Package-Requires: ((emacs "26.3"))
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <https://www.gnu.org/licenses/>.
;;; Commentary:
;; This library provides a minor mode, `piem-gnus-mode', that modifies
;; `piem' variables to teach functions like `piem-inbox' and
;; `piem-am-ready-mbox' how to extract information from Gnus buffers.
;;; Code:
(require 'gnus)
(require 'gnus-art)
(require 'gnus-sum)
(require 'mail-parse)
(require 'message)
(require 'piem)
(defgroup piem-gnus nil
"Gnus integration for piem."
:group 'piem)
(defun piem-gnus-get-inbox ()
"Return inbox name from a Gnus article"
(when (derived-mode-p 'gnus-article-mode 'gnus-summary-mode)
(with-current-buffer gnus-original-article-buffer
(piem-inbox-by-header-match))))
(defun piem-gnus-get-mid ()
"Return the message ID of a Gnus article."
(when (derived-mode-p 'gnus-article-mode 'gnus-summary-mode)
(with-current-buffer gnus-original-article-buffer
(when-let ((mid (message-field-value "message-id")))
(if (string-match (rx string-start (zero-or-more space) "<"
(group (one-or-more (not (any ">"))))
">" (zero-or-more space) string-end)
mid)
(match-string 1 mid)
mid)))))
(defun piem-gnus--from-line (buffer)
"Split a buffer into from-line and the rest of the message.
Returns a cons of the first line of BUFFER, if it is an mboxrd
from-line (or nil if none), and the remaining lines of BUFFER."
(with-current-buffer buffer
(let ((start (point-min))
(end (point-max)))
(goto-char start)
(let* ((eol (line-end-position))
(line (buffer-substring-no-properties start eol)))
(if (string-match-p "^From " line)
(cons line (buffer-substring-no-properties (+ eol 1) end))
(cons nil (buffer-substring-no-properties start end)))))))
(defun piem-gnus-mid-to-thread (mid)
(when (and (derived-mode-p 'gnus-summary-mode)
(string-equal (substring
(mail-header-id (gnus-summary-article-header))
1 -1) ; Remove "<" and ">"
mid))
(save-excursion
;; Cursor has to be at the root of the thread
(gnus-summary-refer-parent-article most-positive-fixnum)
(let ((articles (gnus-summary-articles-in-thread))
messages
;; Just show raw message
(gnus-have-all-headers t)
gnus-article-prepare-hook
gnus-article-decode-hook
gnus-display-mime-function
gnus-break-pages)
(mapc (lambda (article)
(gnus-summary-display-article article)
(let ((from-line-cons
(piem-gnus--from-line gnus-article-buffer)))
(push (format
"%s\n%s\n"
(or (car from-line-cons)
"From mboxrd@z Thu Jan 1 00:00:00 1970")
(replace-regexp-in-string
"^>*From "
">\\&"
(cdr from-line-cons)))
messages)))
articles)
(lambda ()
(insert (apply #'concat (nreverse messages))))))))
(defun piem-gnus-am-ready-mbox ()
"Return a function that inserts an am-ready mbox.
If the buffer has any MIME parts that look like a patch, use
those parts' contents as the mbox, ordering the patches based on
the number at the start of the file name. If none of the file
names start with a number, retain the original order of the
attachments.
If no MIME parts look like a patch, use the message itself if it
looks like a patch."
(when (derived-mode-p 'gnus-article-mode 'gnus-summary-mode)
(cond
(gnus-article-mime-handles
(when-let ((patches (delq nil (mapcar #'piem-am-extract-attached-patch
gnus-article-mime-handles))))
(setq patches (sort patches (lambda (x y) (< (car x) (car y)))))
(cons (lambda ()
(dolist (patch patches)
(insert (cdr patch))))
"mbox")))
(gnus-article-buffer
(when-let ((patch (with-current-buffer gnus-article-buffer
(save-restriction
(widen)
(and (string-match-p
piem-patch-subject-re
(mail-decode-encoded-word-string
(message-field-value "subject")))
(buffer-substring-no-properties
(point-min) (point-max)))))))
(cons (lambda () (insert patch))
"mbox"))))))
;;;###autoload
(define-minor-mode piem-gnus-mode
"Toggle Gnus support for piem.
With a prefix argument ARG, enable piem-gnus mode if ARG is
positive, and disable it otherwise. If called from Lisp, enable
the mode if ARG is omitted or nil."
:global t
:init-value nil
(if piem-gnus-mode
(progn
(add-hook 'piem-am-ready-mbox-functions #'piem-gnus-am-ready-mbox)
(add-hook 'piem-get-inbox-functions #'piem-gnus-get-inbox)
(add-hook 'piem-get-mid-functions #'piem-gnus-get-mid)
(add-hook 'piem-mid-to-thread-functions #'piem-gnus-mid-to-thread))
(remove-hook 'piem-am-ready-mbox-functions #'piem-gnus-am-ready-mbox)
(remove-hook 'piem-get-inbox-functions #'piem-gnus-get-inbox)
(remove-hook 'piem-get-mid-functions #'piem-gnus-get-mid)
(remove-hook 'piem-mid-to-thread-functions #'piem-gnus-mid-to-thread)))
;;; piem-gnus.el ends here
(provide 'piem-gnus)
|